The action of the Steenrod algebra in the cohomology of (Subscript[BF, 4])

Andrzej Kozlowski

Introduction

The aim of this article is to demonstrate the use of Mathematica in computations in algebraic topology.  While Mathematica, which aims to be a general purpose numeric-symbolic program,  can never be as efficient  a tool for research level symbolic computation algebra as more specialized programs, the  dramatic increase in the speed of personal computers has made such use entirely feasible. Moreover, the elegance and ease of the Mathematica programming language make it  often easier to implement mathematical tools far removed form the interests of the majority of Mathematica users and even Mathematica designers. 

 We choose as an example a rather arcane subject: the computation of the action of the Steenrod operations in cohomology of the classifying space of the exceptional Lie group (Subscript[F, 4]). The computation of the cohomology of the classifying spaces of exceptional Lie groups was began by Toda ([T1],[T2]) is still incomplete and an  active area of research.  The computation we perform has been  done by hand by Vavpetic [V] and required a certain amount of manipulation and mathematical cleverness. Here we shall use nothing but the "brute strength" of Mathematica.  In order to perform our computation we have to implement the Steenrod  squaring operations in mod 2 cohomology. The simplicity and elegance of the mathematica programming language make such an implementation almost trivial. The computation we perform here is quite complex and would be impossible to perform "by hand" directly (although of course human intelligence is still far more powerful mathematical tool than the most powerful computers armed with the best symbolic algebra programs).

Summary of basic facts from Algebraic Topology

Lie groups, which generalize groups of invertible matrices and operators are the basic objects of study in several areas of mathematics, as well as being of fundamental importance in physics. A Lie group is simultaneously a topological object (a smooth manifold) and an algebraic one (group) and these two structures are compatible in the sense that the usual algebraic operations (group multiplication, taking the inverse) are given by smooth maps. The simplest Lie groups are of course finite groups which have trivial topological structure. Their natural generalization are compact Lie groups. These have been completely classified (via their associated Lie algebras) into several families (each with infinitely many members) and several so called "exceptional" Lie groups, denoted by (Subscript[G, 2]),  (Subscript[F, 4]), (Subscript[E, 6]),(Subscript[E, 7]),(Subscript[E, 8]). Now, let  G be a compact Lie group. Associated with each such group there is a topological space B G. The characterization of such spaces is an important problem in algebraic topology. An  step in that direction is the computation of their cohomology rings. A famous theorem of Armand Borel reduces the question to invariant theory.

Theorem.(Borel) Let G be a compact connected Lie group with maximal torus T and the Weyl group (Subscript[W, G]). If F is a field of characteristic relatively prime to the order of (Subscript[W, G]) then the projection map B T ⟶ B Ginduces an isomorphism \(\(\(H\^*\)(B\ G, \ F)\)\(\ \)\(≅\)\)\(\(\(H\^*\)(B\ T, \ F)\)\^W\_G\).

This theorem makes it possible to compute cohomology groups of compact Lie groups with rational coefficients and with coefficients in finite fields of characteristic relatively prime to the Weyl group. However, the case of  field coefficients with characteristic dividing the order of the Weyl group is far from simple and is an active area of research. It is also an area in which computer aided algebraic computations are very useful. Most of the computations involve computing the cohomology of the manifold G and passing to the cohomology of B G using the fibration G ⟶ E G ⟶
          B G and the associated Moore-Eilenberg spectral sequence. However, there is another approach which makes use of invariant theory. In his doctoral thesis Vavpetic [V]  computed the cohomology of the exceptional Lie group (Subscript[F, 4]) with coefficients in (Subscript[𝔽, 2])using this approach. The basic idea of the proof is to consider a maximal elementary abelian 2-subgroup of (Subscript[F, 4]). One can show that up to conjugation there is just one such group (Subscript[E, 32]) = (((ℤ/2))^5). By the Weyl group of (Subscript[E, 32])we mean the quotient (Subscript[W, (Subscript[F, 4])])((Subscript[E, 32])) = (Subscript[N, (Subscript[F, 4])])((Subscript[E, 32]))/
          (Subscript[E, 32])of the normalizer of (Subscript[E, 32]) in (Subscript[F, 4]). The Weyl group (Subscript[W, (Subscript[F, 4])])((Subscript[E, 32])) can be viewed as a subgroup of (Subscript[GL, 5])((Subscript[𝔽, 2])) acting on the vector space ((Subscript[𝔽, 2])^5) by linear automorphism. This induces and action on the cohomology \(TraditionalForm\`\(H\^*\)(
        B\ \((ℤ/2)\)\^5, 𝔽\_2)\) which is the polynomial algebra (Subscript[𝔽, 2])[(Subscript[t, 1]), . . . (Subscript[t, 5])]. Vavpetic has shown that the subalgebra of invariants (fixed points) (((Subscript[𝔽, 2])[t1, . . . t5])^((Subscript[W, (Subscript[F, 4])])((Subscript[E, 32]))))is isomorphic to the cohomology of B (Subscript[F, 4]) . He also explicitly constructed the invariants that generate the cohomology ring.
In addition to having the structure of a graded ring the cohomology groups \(TraditionalForm\`\(H\^*\)(X, 𝔽\_2)\)of a topological space X  admit the action of certain natural operations, known as the Steenrod squares [St].  The action of these operations is a powerful invariant (meaning that topologically equivalent spaces not only have isomorphic cohomology rings but also the Steenrod operations act in the same way). Multiplicative properties of the Steenrod operations (the so called "Cartan formula") imply that one only needs to compute their action on the generators of the cohomology ring. This is what we propose to do. First however, we need to describe these generators and implement the Steenrod operations in Mathematica.

Notation

We would like to use the usual superscript notation (Sq^i) for the i-th Steenrod square operation. However, in Mathematica superscripts are already reserved for denoting powers, and treating the i-th Steenrod operation as an i-th power would cause problems. We avoid this by means of the Notation package. This will allow us to use the superscript notation for inputting the i-th Steenrod square while at the same time using the notation Sq[i] when making definitions, which avoids the above mentioned problems. In addition we format the first Steenrod operation (Sq^1) as β, which is the usual thing to do (β is also known as "the Bockstein").

<< "Utilities`Notation`"

Notation[(Sq^i)_ ⟺ Sq[i_]];

\(\(\(Format[Sq[1]] := β;\)\(
\)
    \)\)

Dickson Invariants

The algebra of invariants of (Subscript[GL, n])((Subscript[𝔽, 2])) was calculated by Dickson, who showed that

\(𝔽\_2[t\_1,  ... , t\_n]\^GL\_n[𝔽\_2] = 𝔽\_2[c\_\(n, 0\) ... , 
        c\_\(n, n - 1\)]\)

The generators (Subscript[c, n, i]) are known as Dickson invariants. They are given by the following formula:

\(\(\(\(f\_n\) \((X)\) = \(∏\+\(ν = ∑\+\(i = 1\)\%n\( k\_i\) t\_i\)\((X - ν)\) = \(X\^\(q\^n\) + ∑\+\(i = 0\)\%\(n - 1\)\(\((\(-1\))\)\^\(n - i\)\) \(c\_\(n, i\)\) X\^\(q\^i\) = 
          0\)\)\)\(,\)\)\)

where (Subscript[k, i])are either 1 or 0.

We implement Dickson invariants as follows.

c[n_, i_, t_ : t, k_ : 0] := 
      Block[{ls = Distribute[Table[{0, 1}, {n}], List], x}, 
        PolynomialMod[
          Coefficient[
            Times @@ (x - (Array[Subscript[t, k + #1] &, {n}] . #1 &) /@ 
                    ls), (x^((2^i)))], 2]]

The third argument is the letter we use to denote the variables in our invariant. By always take that to be t but other letters are possible. The fourth argument determines the initial value of the index of this variable. For example

c[3, 2]

c[3, 2, t, 1]

Dickson invariants tend to be very complicated.

c[4, 2]

We shall be working in graded rings, so we assign all the indeterminates the degree 1.

dim[Subscript[t, i_]] = 1;

Working mod 2

We shall need to use the Steenrod operations in cohomology. These exists whenever the coefficient are taken in a field of finite characterisitc, but we shall only consider the case of coefficients in (Subscript[F, 2]). We would like to work mod 2 but also to be able to switch to characteristic 0 when convenient. First, we make a list of functions which accept the option Modulus:

functions = 
      ToExpression /@ 
        Select[DeleteCases[
            Names["System`*"], _?(StringTake[#1, 
                      1] == "$" &)], ! FreeQ[Options[Symbol[#1]], 
                Modulus] &]

The next function will automatically set the modulus to p for all the function that accept this option.

FunctionsMod[p_] := 
      Scan[SetOptions[#1, Modulus -> p] &, functions]

We can now switch all the functions in the above list to working modulo 2 and back to characteristic 0 (or any other).

Here is how it works

FunctionsMod[2]

Expand[(((x + 1))^4)]

FunctionsMod[0]

Expand[(((x + 1))^4)]

In what follows we work  mod  2.

FunctionsMod[2]

The Steenrod Squares

Next we implement the Steenrod operations . This implementation contains several superfluous rules, whose presence however seems to improve performance. The implementation is obtained basically just by copying the properties of the Steenrod operations from any text on algebraic topology and writing them down using Mathematica syntax. The naturalness and easy of this construction seem to me unmatched by other symbolic algebra programs.  The last two rules are the famous Cartan and Adem formulas. (The latter one is not needed for the computations performed below, but we include it for completeness).

c[n_, m_] := 
        Mod[((n!)/((n - m)! m!)), 2];
Sq[l_List][x_] := Fold[Sq[#2][#1] &, x, l];
dim[Sq[i_][x_]] := i + dim[x];
Sq[0] = Identity;
Sq[1][Sq[1][x_]] := 0;
Sq[1][Sq[i_?EvenQ][x_]] := Sq[i + 1][x];
Sq[1][Sq[i_?OddQ][x_]] := 0;
Sq[i_][0] = 0;
Sq[i_][k_Integer x_] := Mod[k, 2] Sq[i][x];
Sq /: Sq[i_][x_ + y_] := 
        PolynomialMod[Sq[i][x] + Sq[i][y], 2];
dim[k_?IntegerQ] := 0;
dim[x_ y_] := dim[x] + dim[y];
\(\(dim[x_\^n_] := n\ dim[x];\)\)
dim[Sq[i_][x_]] := i + dim[x];
Sq[i_][0] := 0;
Sq[i_][a_] /; dim[a] < i := 0;
Sq[i_][a_] /; dim[a] == i := (a^2);
\(\(\(Sq[i_]\)[x_\^k_Integer?Positive] /; dim[x] == 1 := 
        c[k, i]\ x\^\(i + k\);\)\)
Sq[k_][x_ y_] := 
        PolynomialMod[(∑_(i = 0)^k) Sq[i][x] Sq[k - i][y], 
          2];
Sq[a_][Sq[b_][x_]] /; 0 < a < 2 b := 
        PolynomialMod[(∑_(j = 0)^(Floor[(a/2)]))c[b - 1 - j, 
                a - 2 j] Sq[a + b - j][Sq[j][x]], 2];

Computation of the action of  Steenrod Squares on the invariants.

We now apply this to compute the action of the Steenrod operations on the cohomology of the exceptional Lie group (Subscript[F, 4]).

However, it is first of all necessary to construct the invariants in (((Subscript[𝔽, 2])[t1, . . . (Subscript[t, 5])])^((Subscript[W, (Subscript[F, 4])])((Subscript[E, 32])))) that  generate the cohomology ring. Vavpetic constructs such invariants out of Dickson invariants in (((Subscript[𝔽, 2])[(Subscript[t, 3]),(Subscript[t, 4]) , (Subscript[t, 5])])^(GL(3, (Subscript[𝔽, 3])))) and (((Subscript[𝔽, 2])[(Subscript[t, 1]),(Subscript[t, 2]) ])^(GL(2, (Subscript[𝔽, 3])))). The general nature of this construction is explained in [K].  In fact the invariance of the elements constructed by Vavpetic can be also verified by a direct Mathematica computation, but as this is very time consuming here we only implement them in Mathematica without any further comment.

First of all, we define the following three generators of degree 4, 6 and 7 , in which are simply Dickson invariants, that is, invariants of the action of  (Subscript[GL, 3])((Subscript[𝔽, 2])) on (Subscript[𝔽, 2])[(Subscript[t, 3]),(Subscript[t, 4]) , (Subscript[t, 5])]. By thinking of  (Subscript[GL, 3])((Subscript[𝔽, 2])) as a subgroup of (Subscript[GL, 5])((Subscript[𝔽, 2])), which acts trivially on (Subscript[t, 1])and (Subscript[t, 2])we obtain three invariant elements of degree 4, 6 and 7.

(Subscript[y, 4]) = c[3, 2, t, 2]

(Subscript[y, 6]) = c[3, 1, t, 2]

(Subscript[y, 7]) = c[3, 0, t, 2]

Two more invariants, of degree 16 and 24 and involving both (Subscript[t, 1])and (Subscript[t, 2])are defined as follows:

(Subscript[a, i])_ := 
      (Subscript[t, i]^8) + (Subscript[y, 4]) (Subscript[t, i]^4) + (Subscript[y, 6]) (Subscript[t, i]^2) + (Subscript[y, 7]) (Subscript[t, i])

(Subscript[y, 16])=(((Subscript[a, 1]))^2)+(Subscript[a, 2]) (Subscript[a, 1])+(((Subscript[a, 2]))^2);

(Subscript[y, 24])=(Subscript[a, 1]) (Subscript[a, 2]) ((Subscript[a, 1])+(Subscript[a, 2]));

We do not print out these as they are represented by rather long expressions,  even with mod 2 coefficients, indeed we have:

Length[PolynomialMod[Expand[(Subscript[y, 24])], 2]]

Of course we can now simply apply the Steenrod operations to our invariants directly and even get some useful results, such as

(Sq^2)[(Subscript[y, 7])]

However

(Sq^4)[(Subscript[y, 7])]

is not what we want, since we would like to express each invariant generator in terms of the other ones. Of course this is just the job for GroebnerBasis and PolynomialReduce [CLS]. The problem is that we can't get our output in terms of  the (Subscript[y, i]) since Mathematica will automatically express them in terms of the (Subscript[t, i]). To cope with this we introduce new variables, (Subscript[Y, 4]),(Subscript[Y, 6]),(Subscript[Y, 7]), (Subscript[Y, 16]), (Subscript[Y, 24])which we think of as new set of names for (Subscript[y, 4]), (Subscript[y, 6]),(Subscript[y, 7]),(Subscript[y, 16])and (Subscript[y, 24]) (If we wished to make it look as if we were using the same symbols we could define (Subscript[Y, 4])=HoldForm[(Subscript[y, 4])] etc.) We can then express the action of the Steenrod squares on the little y's in terms of the large Y's.

ideal1 = {(Subscript[Y, 4]) - c[3, 2, t, 2], (Subscript[Y, 6]) - c[3, 1, t, 2], 
        (Subscript[Y, 7]) - c[3, 0, t, 2]};

ideal2 = Join[ideal1, {(Subscript[Y, 16]) - (Subscript[y, 16]), (Subscript[Y, 24]) - (Subscript[y, 24])}];

vars1 = Join[Table[t[i], {i, 3, 5}], {(Subscript[Y, 4]), (Subscript[Y, 6]), (Subscript[Y, 7])}];

vars2 = 
      Join[Table[t[i], {i, 1, 5}], {(Subscript[Y, 4]), (Subscript[Y, 6]), (Subscript[Y, 7]), (Subscript[Y, 16]), 
          (Subscript[Y, 24])}];

groebner1 = GroebnerBasis[ideal1, vars1];

groebner2 = GroebnerBasis[ideal2, vars2];

Now we can compute the actions of the  Steenrod operations on the invariants (of course we only need to compute the action of Steenrod squares in dimensions lees than the dimension of the invariant, the remaining squares act trivially by definition).

Table[PolynomialReduce[(Sq^((2^i)))((Subscript[y, 4])),groebner1,vars1][[2]],{i, 0, 2}]

Table[PolynomialReduce[(Sq^((2^i)))((Subscript[y, 6])),groebner1,vars1][[2]],{i, 0, 2}]

Table[PolynomialReduce[(Sq^((2^i)))((Subscript[y, 7])),groebner1,vars1][[2]],{i, 0, 2}]

Table[PolynomialReduce[(Sq^((2^i)))((Subscript[y, 16])),groebner2,vars2][[2]],{i, 0, 4}]

Table[PolynomialReduce[(Sq^((2^i)))((Subscript[y, 24])),groebner2,vars2][[2]],{i, 0, 4}]

These results agree with those obtained by Vavpetic.

References

[CLS]  D. Cox, J. Little, D. O'Shea, Using Algebraic Geometry, Springer-Verlag, 1998.
[K]  M. Kameko, Rings of Invariants derived from Dickson Invariants (pre-print)
[S]  L. Smith, Polynomial Invariants of Finite groups, A K Peters Ltd, 1995.
[St]  N. E. Steenrod, Cohomology Operations, written and revised by D.B.A. Epstein, Princeton University Press, 1962
[T1]  H.  Toda, Cohomology of classifying spaces of exceptional Lie groups, Manifolds, pp. 265-271, Tokyo 1973
[T2]  H. Toda, Cohomology mod 3 of the classifying space (Subscript[BF, 4]) of the exceptional Lie group (Subscript[F, 4]), J. Math. Kyoto Univ. 13 (1972), 97-115
[V]  A. Vavpetic. Homotopy Characterization of classifying spaces of compact Lie groups. University of Lubljana doctoral thesis, 2000.
[W]  C. Wilkerson, A primer on the Dickson Invariants, a corrected version of the paper published in Contemp. Math. 19 (1983), 421-432